Hoy vamos con la segunda y última entrega del Sistema Garrapata.

Hoy voy a explicaros de manera detallada como configurar vuestra plataforma para poder usar el sistema, para ello usaremos ProRealTime. En vez de usar el indicador Nobleza usaré uno estándar en su lugar: Volatilidad histórica o Chaikin volatilidad.

• Paso 1: Abrimos el gráfico en semanal, por ejemplo el SP500:

• Paso 2: Añadimos la media móvil ponderada de 22 sesiones:

• Paso 3: Añadimos el indicador Chaikin, volatilidad con 20 y 45 como parámetros:

Y ya está! Lo único que tenemos que hacer es sentarnos tranquilamente el fin de semana y pegar un repasillo a los mercados a ver qué valores cumplen los criterios. Para hacerlo de una manera más o menos estructurada podemos hacer como hacen los weinstenianos, es decir, mirar primero los índices para ver qué mercados tienen un sesgo alcista, y luego profundizar en cada uno de ellos.

Recuerdo la estrategia: Si la volatilidad es descendiente y la media móvil se acaba de poner verde (alcista), el lunes en la apertura compramos y ponemos un trailing stop de un 10% que iremos subiendo cada fin de semana. Si la volatilidad se gira al alza el stop pasa a ser de un 7%.

Un saludo a tod@s.

Esto nos lleva a pensar casi sin ningún género de dudas que las propias manos fuertes muchas veces son las que tumban al valor para provocar un pánico en las manos débiles para a continuacion recoger todo el papel y hacer subir al valor dejando al resto de la gente fuera sin apenas tiempo para recuperarse del susto.

Quería presentaros el indicador que he estado desarrollando los últimos meses y que muchos ya conoceis. Se trata del Gestur-Manipulacion.

¿Qué es el Gestur-Manipulacion?

Se trata de un indicador cuyo principal propósito es el reflejar de una manera gráfica la distribución de las fuerzas del mercado. Concretamente la mano fuerte y la mano débil.

¿Qué son las fuerzas del mercado? ¿Mano fuerte? ¿Mano débil? ¿Mande?

En primer lugar queria aclarar que todo esto es una simplificación de todos los factores que influyen en el comportamiento de la bolsa, pero si entendemos la bolsa como un invento para sacarle el dinero a la gente (que es lo que pienso que es) en general habrá dos grandes grupos: los experimentados y los inexpertos; los ricos y los pobres; los que tienen información privilegiada y los que no; los que van por delante y los que llegan tarde a los movimientos. En definitiva la mano fuerte y la mano débil.

¿Como sabe el indicador quien está comprando y vendiendo?

No lo sabe. Los datos que recibimos de bolsa son apertura, cierre, máximo, mínimo y volumen. A partir de esos datos no podemos adivinar, pero si suponer ciertas premisas basadas en observaciones pasadas, por ejemplo:

• Las manos debiles suelen operar en el sentido del precio y habitualmente tarde, es decir, contribuyen a mantener la direccion actual del precio incluso a acelerarla.
• Las manos fuertes se anticipan y son capaces de mover el mercado. Desde luego tienen mas poder que las débiles.

Aparte de estas premisas el indicador también tiene en cuenta rangos intradiarios, distancia de la apertura respecto cierre anterior, aumentos o disminuciones de volumen en funcion de situaciones…

¿Como funciona?

A la hora de decidir como mostrar esta información la verdad es que me he basado, o casi plagiado, el famoso Koncorde de Blai5. Las manos fuertes vienen representadas por una linea y area azules y las manos débiles por verdes.

Ejemplo:

Supongo que en este ejemplo habra quedado bastante claro, pero por si acaso os dejo 3 videos explicativos sobre la idea y funcionamiento del indicador:

[There is a video that cannot be displayed in this feed. Visit the blog entry to see the video.]

[There is a video that cannot be displayed in this feed. Visit the blog entry to see the video.]

[There is a video that cannot be displayed in this feed. Visit the blog entry to see the video.]

¿Cómo me lo instalo?

A continuación os pongo el código fuente del indicador. Para instalarlo solo teneis que darle a “Añadir indicador” en ProRealTime, copiar y pegar el texto en la ventana y pulsar “Validar programa”. Luego teneis que poner las variables azul y verde como histograma, y lazul y lverde como linea pero con más anchura, el resto dejar como está. Que lo disfrutéis:

rem ---------------------Manipulacion---------------------

rem Indicador que trata de diferenciar que parte del volumen de negociación
rem corresponde a manos débiles y a manos fuertes.
rem Creado por gestur

rem Variables que controlan el rango adaptativo del area azul y verde.

once divazul=1
once divverde=1

nvol=80
adapt=2
zoomazul=5
zoomverde=5

rem Periodo 1 y 2 de las medias moviles que se encargan de detectar cambios de direccion.
n1=50
n2=3
n3=6

m1 = Average[n1](close)
m2 = Average[n2](close)
m3 = Average[n3](close)

volm = average[nvol](volume)
diferencia1 = Average[2](m2) - Average[2](m1)
diferencia2 = Average[2](m3) - Average[2](m1)
mani1 = (m2 - m1 - diferencia1) / 2
mani2 = m3 - m1 - diferencia2
mani = mani1 + mani2
diferencia = diferencia1

volp = volume / volm

if volp = 0 then
 volp = 1
 volm = 1
endif

a = (diferencia / open) * volp
b = (close - m1) / close
c = (open - close[1]) / close[1]
d = (close - open) / close

rem Calculamos las franjas azul y verdes en funcion de los dos supuestos y los adaptamos al rango dinamico.
azul = (mani + ((d-c) * volp)) * volp - a
verde = b * volp

if volp <> 0 then
 if averde[1] > 1 or averde[1] < -1 then
  divverde = divverde * (1 + adapt / 50)
 else
  divverde = divverde / (1 + adapt / 600)
 endif

 if aazul[1] > 1 or aazul[1] < -1 then
  divazul = divazul * (1 + adapt / 50)
 else
  divazul = divazul / (1 + adapt / 600)
 endif

 averde = verde / divverde * zoomverde
 aazul = azul / divazul * zoomazul
endif

if averde > 8 then
 averde = 8
endif
if averde < -8 then
 averde = -8
endif
if aazul > 8 then
 aazul = 8
endif
if aazul <-8 then
 aazul = -8
endif

rem Ajustamos el indice de manipulacion para que se mantenga en un rango razonable.
amani=mani/(highest[nvol](mani)-lowest[nvol](mani))*2

return  0 COLOURED (0,0,0) as "cero", aazul COLOURED(0,255,255) as "azul",  averde COLOURED(102,255,102) as "verde", aazul COLOURED (0,51,255) as "lazul",  averde COLOURED (0,153,51) as "lverde", amani COLOURED (153,102,0) as "mani"